Novo Cleo para Gangs

    Compartilhe

    RafaQN
    Mensagens Nível 2
    Mensagens Nível 2

    Mensagens : 97
    Reputação : 12
    Idade : 23
    Localização : São Paulo - SP

    Novo Cleo para Gangs

    Mensagem por RafaQN em Sex 15 Jan 2016, 11:27

    Galera, estava vendo aquele mod de fazer com que a Triad e os Aztecas fossem convocados para a a gangue do CJ, mas só que ele tem o bug de não ser compatível com missões com o Sweet onde ele faz parte de sua gangue.
    Tentei refazer/corigir o script, até que deu certo, mas acho que ele pode crasheiar o jogo ainda:

    Código:
    {$CLEO .cs}
    0@ = 0
    while true
        wait 200
        //Verificar se passou no critério de missões do Wu Zi Mu
        if  $Wuzimu_Total_Passed_Missions > 0
        then
            0746: set_acquaintance 1 of_actors_pedtype 8 to_actors_pedtype 13
            0746: set_acquaintance 1 of_actors_pedtype 13 to_actors_pedtype 8
            0746: set_acquaintance 1 of_actors_pedtype 13 to_actors_pedtype 0
            if  Player.WantedLevel($PLAYER_CHAR) > 0
            then
                0746: set_acquaintance 4 of_actors_pedtype 13 to_actors_pedtype 6
            else
                0746: set_acquaintance 2 of_actors_pedtype 13 to_actors_pedtype 6   
            end
        end
        //Verificar se passou no critério de missões do Cesar
        if  $Riot_Total_Passed_Missions > 1
        then
            0746: set_acquaintance 1 of_actors_pedtype 8 to_actors_pedtype 14
            0746: set_acquaintance 1 of_actors_pedtype 14 to_actors_pedtype 8
            0746: set_acquaintance 1 of_actors_pedtype 14 to_actors_pedtype 0
            if  Player.WantedLevel($PLAYER_CHAR) > 0
            then
                0746: set_acquaintance 4 of_actors_pedtype 14 to_actors_pedtype 6
            else
                0746: set_acquaintance 2 of_actors_pedtype 14 to_actors_pedtype 6   
            end 
        end
        //Verificar se passou no critério de missões anteriores
        if and
        $Riot_Total_Passed_Missions > 1
        $Wuzimu_Total_Passed_Missions > 0
        then
            0746: set_acquaintance 1 of_actors_pedtype 13 to_actors_pedtype 14
            0746: set_acquaintance 1 of_actors_pedtype 14 to_actors_pedtype 13
        end
        //Chamar um ped Triad ou Azteca para a gang
        0AD2: 1@ = player $PLAYER_CHAR targeted_actor
        if and
        00E1:  player 0 pressed_key 8
        056D:  actor 1@ defined
        then
            089F: get_actor 1@ pedtype_to 4@
            if and
            4@ == 13
            $Wuzimu_Total_Passed_Missions > 0
            then    gosub @MOREGANG
            end
            if and
            4@ == 14
            $Riot_Total_Passed_Missions > 1
            then    gosub @MOREGANG
            end
        end
    end

    :MOREGANG
    0631: put_actor 1@ in_group $PLAYER_GROUP
    0626: decrease_float_stat 336 by 1.0
    0624: add 1.0 to_float_stat 336
    0A1D: AS_actor 1@ rotate_to_and_look_at_actor $PLAYER_ACTOR
    04ED: load_animation "GANGS"
    repeat
        wait 0
    until  04EE:  animation "GANGS" loaded
    0605: actor 1@ perform_animation "INVITE_YES" IFP "GANGS" framedelta 4.0 loop 0 lockX 1 lockY 1 lockF 0 time -1
    04EF: release_animation "GANGS"
    //Dá para marcar os membros de gangues que nem na grove, mas preciso ver como eles seriam desmacados quando os dispensarem
    http://Marker.CreateAboveActor(2@, 1@)
    //0165: set_marker 2@ color_to 1
    if  02D8:  actor 1@ current_weapon == 0
    then
        0247: load_model 346
        038B: load_requested_models
        Actor.GiveWeaponAndAmmo(1@, Pistol, 99999)
        01B9: set_actor 1@ armed_weapon_to 22
        0249: release_model 346
    end
    return

    Pode até rolar de fazer um "cleo pack" de mods para gangues, diminuindo a quantidade de scripts, assim como estou fazendo com o 'Health & Armour' (apesar desse ter uns bem originais fuckyea ).

    Ai quem souber de melhorias e entre outras coisas a respeito desse dei me um toque por aqui, flw...

      Data/hora atual: Dom 22 Jan 2017, 00:41